Glengamoi (Forum) · AspHeute · .NET Heute (RSS-Suche) · AspxFiles (Wiki) · .NET Blogs

ADO und ASP - Datenbanken einmal näher betrachtet

Geschrieben von: Christian Koller
Kategorie: Datenbank

This printed page brought to you by AlphaSierraPapa

Kaum eine anspruchsvolle Website die heute nicht mit einer Datenbank arbeitet. Ob Veranstaltungskalender, Produktkatalog, Mitgliederdatenbank, Gästebuch, personalisierte Dienste oder allgemein veränderliche Daten - all dies läßt sich mit Hilfe der Kombination ASP Skripts auf der Webserver Seite und einer Datenbank auf der anderen Seite verwirklichen.

Betrachten wir einmal das Bindeglied zwischen diesen beiden Technologien näher. Von ASP aus greift man am einfachsten über ADO (ActiveX Data Objects) und das zugehörige ADODB Objekt auf Datenquellen zu. Die Verbindung zwischen ADO (und der darunterliegenden OLE DB, Object Linking and Embedding Database) und der Datenbank wird meist über ODBC (Open DataBase Connectivity) hergestellt, das Applikationen einen weitgehend einheitlichen Zugriff auf verschiedenste Datenquellen erlaubt. Aber alles schön der Reihe nach.

ADO stellt die Objekte zur Verfügung mit deren Hilfe ein ASP Skript eine Verbindung zur Datenbank aufbauen und Daten auf vielfältigste Weise manipulieren kann. Die wichtigsten ADO Objekte sind:

Connection (Datenbankverbindung) - Repräsentiert die Verbindung zur Datenquelle
Recordset (Sammlung von Datensätzen) - Besteht aus den Datensätzen die aus einer Datenbankabfrage stammen und dem zugehörigen Cursor, der auf den aktuellen Datensatz zeigt.
Field (Datenfeld) - Enthält Daten einer Datenbankspalte und Informationen über diese Daten wie Datentyp, Datenlänge und Ähnliches. Das Recordset Objekt stellt dabei die Fields Collection zur Verfügung, die alle Field Objekte eines Datensatzes beinhaltet.
Property (Eigenschaft) - Erlaubt den Zugriff auf dynamische Informationen eines ADO Objektes die von der Datenquelle oder der Datenanbindung (wie ODBC) zur Verfügung gestellt werden.
Error (Fehler) - Enthält ausführliche Fehlerinformationen bei Datenbankzugriffen. Auf alle Fehler eines Datenbankzugriffes kann durch die Errors Collection zugegriffen werden.
Command (Befehl) - Erlaubt es einzelne Datenbankabfragen zu definieren, so daß ein mehrmaliger Einsatz mit verschiedenen Parametern rascher durchgeführt werden kann .
Parameter (Parameter) - Stellt einen einzelnen Parameter (Argument) eines Command Objektes für eine parametrisierte Abfrage oder einen Zugriff auf eine "Gespeicherte Datenbankprozedur" dar.

Normalerweise findet man mit den Objekten Connection, Recordset und Field das Auslangen.

Wie sieht nun eine einfache Datenbankabfrage aus? Das folgende ASP Skript öffnet eine Verbindung zur Nordwind Datenbank, die mit Microsoft Access 97/2000 und SQL Server 7.0 (deutsche Versionen) ausgeliefert wird. Weiters liest es die Datensätze der Tabelle Artikel aus, die in die Kategorie Meeresfrüchte fallen, um die Werte der Spalten Artikel-Nr und Artikelname schließlich im Browser anzuzeigen.

<%
Response.Expires=0
Response.AddHeader "Pragma","no-cache"
Response.AddHeader "cache-control", "no-store"

Response.Write "Abfrageergebnis:<br>" & vbcrlf
Set conn = Server.CreateObject("ADODB.Connection")
conn.Open "DSN=NW;USR=sa;PWD="
strSQL = "SELECT Artikel.[Artikel-Nr], Artikel.Artikelname "
strSQL = strSQL & "FROM Artikel INNER JOIN Kategorien "
strSQL = strSQL & "ON Artikel.[Kategorie-Nr]=Kategorien.[Kategorie-Nr] "
strSQL = strSQL & "WHERE Kategorien.Kategoriename = 'Meeresfrüchte' "

Set rs = conn.Execute(strSQL)

Do While Not(rs.EOF)
	Response.Write "" & rs("Artikel-Nr") & " : "
	Response.Write "" & rs("Artikelname") & "<BR>" & vbcrlf
	rs.MoveNext
Loop

rs.Close
conn.Close
%>

In kurzen Worten erklärt speichert das Skript eine Instanz des Connection Objektes in der Variable conn, um dann die Datenbankverbindung mit dem Befehl conn.Open herzustellen.

Der Parameter für conn.Open enthält den Datenquellennamen, im englischen Original DSN (Data Source Name) genannt, der im ODBC Datenquellenadministrator korrekt definiert sein muß.

Danach wird das SQL (Structured Query Language) Statement, das die Datenbankabfrage definiert, in der Variable strSQL gespeichert. Die SQL Abfrage sieht im Klartext wie folgt aus.

SELECT Artikel.[Artikel-Nr], Artikel.Artikelname 
	FROM Artikel INNER JOIN Kategorien
	ON Artikel.[Kategorie-Nr]=Kategorien.[Kategorie-Nr]
	WHERE Kategorien.Kategoriename = 'Meeresfrüchte'

Das Ergebnis dieser SQL Abfrage wird im Recordset mit dem Namen rs von ADO bereitgestellt, die Werte der Felder ausgelesen und zum Browser geschickt.

Zu guter letzt macht das Skript noch Ordnung und schließt das Recordset und die Connection um deren Ressourcen wieder zur Verfügung zu stellen.

Was schon anhand dieses kleinen Beispieles ersichtlich ist: Um Daten aus einer Datenbank in einem ASP Skript verwenden zu können, ist es durchaus hilfreich, wenn man ein gesundes Wissen über die Grundlagen der Datenbankprogrammierung und der Sprache SQL hat.

ADO bietet darüber hinaus noch einige andere Möglichkeiten um mit wenig Aufwand Daten zu manipulieren. Die Verwendung hängt wie so oft vom Einsatzgebiet und persönlichen Vorlieben ab.

This printed page brought to you by AlphaSierraPapa

ADO und ASP - Datenbanken einmal näher betrachtet

Verwandte Artikel